SHADE_Y3/Assets/Shaders/TestCube_Tile_VS.glsl

#version 450
#extension GL_KHR_vulkan_glsl : enable

//#include "ShaderDescriptorDefinitions.glsl"


layout(location = 0) in vec3 aVertexPos;
layout(location = 1) in vec2 aUV;
layout(location = 2) in vec3 aNormal;
layout(location = 3) in vec3 aTangent;
layout(location = 4) in mat4 worldTransform;
layout(location = 8) in uvec2 integerData;

struct MatPropData
{
  vec2 tileMult;
  uint textureIndex;
};

layout(location = 0) out struct
{
  vec4 vertPos; // location 0
  vec2 uv; // location = 1
  vec4 normal; // location = 2

} Out;

// material stuff
layout(location = 3) out struct
{
  int materialIndex;
  uint eid;
  uint lightLayerIndex;

} Out2;

layout(set = 1, binding = 0) uniform CameraData
{
  vec4 position; 
  mat4 vpMat;
  mat4 viewMat;
  mat4 projMat;
} cameraData;

layout (std430, set = 2, binding = 0) buffer MaterialProperties     // For materials 
{
  MatPropData data[];
} MatProp;

void main()
{
  Out2.materialIndex = gl_InstanceIndex;
  Out2.eid             = integerData[0];
  Out2.lightLayerIndex = integerData[1];

  // for transforming gBuffer position and normal data
  mat4 modelViewMat = cameraData.viewMat * worldTransform;

  // gBuffer position will be in view space
  Out.vertPos = modelViewMat * vec4(aVertexPos, 1.0f);

  // uvs for texturing in fragment shader
  Out.uv = aUV * MatProp.data[gl_InstanceIndex].tileMult;

  mat3 transposeInv = mat3 (transpose(inverse(modelViewMat)));

  // normals are also in view space
  Out.normal.rgb = transposeInv * aNormal.rgb;
  Out.normal.rgb = normalize (Out.normal.rgb);

  // clip space for rendering
  gl_Position = cameraData.vpMat * worldTransform * vec4 (aVertexPos, 1.0f);
}